Benutzung von Hochkomma und Gänsefüßchen
Wir benutzen sie als Trennzeichen, um Alpha-Strings zuzuweisen oder zu selektieren oder für Heading, Footing, Subhead und Subfoot u.a. Zwecke.
Hier folgen Beispiele, wie Sie Hochkomma und Gänsefüßchen trotzdem im Datenteil, in der Selektion oder im Heading, Footing, Subhead und Subfoot verwenden können.
1. Darstellung von Gänsefüßchen (double quotes) im Heading, Footing, Subhead oder Subfoot
In Focus werden Zeilen für Berichtsüberschrift (HEADING), Fußnoten (FOOTING), Gruppenwechsel-Köpfe (SUBHEAD) und Gruppenwechsel-Füße (SUBFOOT) mit folgender Syntax erzeugt:
HEADING
" ich bin die erste Zeile der Überschrift"
Aufgabenstellung: Wie bekomme ich ein Gänsefüßchen (double quote) in die Überschrift ?
Im FOCUS-Programm:
DEFINE FILE CAR
DQUOTES/A1 WITH COUNTRY = '"';
END
TABLE FILE CAR
HEADING
"<DQUOTES Länderbericht <DQUOTES"
" "
PRINT COUNTRY
END
Berichtsanzeige:
2. Darstellung von Hochkomma in der Spaltenüberschrift (Variante 1)
Im FOCUS-Programm:
TABLE FILE CAR
COUNTRY AS ,'COUNTRY'
END
Berichtsanzeige:
3. Darstellung von Hochkomma in der Spaltenüberschrift (Variante 2)
Im FOCUS-Programm:
DEFINE FILE PERSONAL
NACHNAME,VORNAME/A27=NACHNAME || (', ' | VORNAME);
END
TABLE FILE PERSONAL
HEADING
" ANZEIGE AUS PERSONAL DATEI "
PRINT JG ABT
BY NACHNAME,VORNAME
END
Berichtsanzeige:
4. Darstellung von Hochkomma im Alpha-Feld (Datenteil - Variante 1)
Alpha-Strings werden Feldern in Hochkommas zugewiesen z.B.
FELD/A5 = ’abcde’;
Aufgabenstellung: Wie kann man einem Feld ein Hochkomma als Inhalt zuweisen ?
Im FOCUS-Programm:
DEFINE FILE CAR
WESSEN/A10=IF COUNTRY EQ 'JAPAN' THEN 'ASIA''S' ELSE 'EUROPE''S';
END
TABLE FILE CAR
COU
WESSEN
END
Berichtsanzeige:
5. Selektion von Hochkomma im Alpha-Feld (mit WHERE)
Alpha-Strings werden in der WHERE-Klausel zur Selektion zwischen Hochkommas abgefragt z.B.
WHERE FELD EQ ’abcde’
Aufgabenstellung: Wie fragt man ein Feld nach einem Hochkomma ab ?
Im FOCUS-Programm:
DEFINE FILE CAR
WESSEN/A10=IF COUNTRY EQ 'JAPAN' THEN 'ASIA''S' ELSE COUNTRY;
END
TABLE FILE CAR
COU
WESSEN
WHERE WESSEN CONTAINS ''''
END
Berichtsanzeige:
Anzeige der WHERE-Klausel im Quelltext des Browsers:
</HTML>
<!-- (time 113925) -->
<!-- -RUN
-GOTO TEIL4
-TEIL4
DEFINE FILE CAR
WESSEN/A10=IF COUNTRY EQ 'JAPAN' THEN 'ASIA''S' ELSE COUNTRY;
END
TABLE FILE CAR
COU
WESSEN
WHERE WESSEN CONTAINS ''''
END
-RUN
0 NUMBER OF RECORDS IN TABLE= 1 LINES= 1
-->
<!-- (time 113925) -->
<!--
6. Darstellung von Hochkomma im Alpha-Feld (Datenteil - Variante 2)
Alpha-Strings werden Feldern in Hochkommas zugewiesen z.B.
FELD/A5 = ’abcde’;
Aufgabenstellung: Wie kann man einem Feld ein Hochkomma als Inhalt zuweisen ?
Im FOCUS-Programm:
DEFINE FILE CAR
NEWCOUNTRY/A12 = ''''||COUNTRY||'''' ;
END
TABLE FILE CAR
PRINT COUNTRY NEWCOUNTRY
END
Berichtsanzeige:
7. Darstellung von Hochkomma in Dialog-Manager-Variable
Alpha-Strings können Dialog-Manager-Variablen in Hochkommas zugewiesen z.B.
-SET &FELD = ’abcde’;
Aufgabenstellung: Wie kann man einer Dialog-Manager-Variablen ein Hochkomma als Inhalt zuweisen ?
Im FOCUS-Programm:
-SET &&FELD = '''LAND''';
-RUN
? &&
TABLE FILE CAR
HEADING
" siehe &&FELD"
PRINT CAR AS LAND
END
Berichtsanzeige:
